<harker>
<exampleName>Harker</exampleName>
<category>cp</category>
<solver>NLPEC</solver>
<inputMethod>GAMS</inputMethod>
<priority>short</priority>
<model>
$title Models of Spatial Competition in MCP Form (HARKMCP,SEQ=128)
*
*  A SPATIAL EQUILIBRIUM MODEL IS USED TO DEMONSTRATE DIFFERENT
*  WAYS OF MODELING MARKET BEHAVIOUR. AN EARLIER VERSION (HARKER)
*  USED OPTIMISATION TO SOLVE THESE PROBLEMS. IN THIS VERSION,
*  THE PROBLEMS ARE SOLVED AS COMPLEMENTARITY PROBLEMS.
*
*  Reference: Harker P T, Alternative Models of Spatial Competition,
*             Operations Research, 34(3), pp 410-425, (1986).
*

SETS  N     NODES    / ONE, TWO, THREE, FOUR, FIVE, SIX /
      L(N)  REGIONS  / ONE, TWO, THREE /;

ALIAS (L,LP),(N,NP);

*       LINEAR DEMAND FUNCTION:

*               D(P) = (RHO - P) / ETA

*       LINEAR MARGINAL COST FUNCTION:

*               C(Y) = ALPHA + 2 * BETA * Y


TABLE COEFS(L,*)  DEMAND AND SUPPLY DATA

            ALPHA   BETA     RHO      ETA

ONE         1       0.5      19       0.2
TWO         2       0.4      27       0.01
THREE       1.5     0.3      30       0.3


*       THE MARKET IS STRUCTURED ON A NETWORK.  THE TOTAL TRANSPORT COST
*       ON THE ij LINK IS GIVEN BY:

*               TCij = KAPPAij  * Xij + NUij * Xij^3

TABLE PAIRS(N,NP,*)  TRANSPORT DATA

           KAPPA     NU
ONE.FOUR     1       .5
ONE.FIVE     2       .2
TWO.SIX      3       .3
THREE.SIX    1       .4
FOUR.ONE     2       .3
FOUR.FIVE    1       .1
FOUR.SIX     1       .1
FIVE.ONE     3       .5
FIVE.FOUR    2       .2
FIVE.SIX     1      1.0
SIX.TWO      2       .25
SIX.THREE    2       .2
SIX.FOUR     1       .9
SIX.FIVE     3       .8

SET ARC(N,NP) ACTIVE ARCS;
ARC(N,NP) = YES$PAIRS(N,NP,"KAPPA");

POSITIVE VARIABLES

                D(L)            CONSUMER DEMAND,
                C(N)            MARGINAL COST,
                Y(N)            PRODUCTION,
                X(N)            TOTAL SALES,
                P(L)            CONSUMER PRICE,
                T(N,NP)         TRANSPORT;

EQUATIONS

*       EQUATIONS FOR BASIC MODEL:

                DEMAND(L)       INVERSE DEMAND FUNCTION (LINEAR),
                SUPPLY(N)       NODE BALANCE CONDITION,
                MKT(L)          MARKET CLEARANCE,
                MRMC(L)         PRICING EQUATION,
                TCOST(N,NP)     TRANSPORT COST EQUATION,
                COST(N)         MARGINAL COST OF SUPPLY;

*       MARKET STRUCTURE FLAGS:

SCALAR  MONOPOLY        INDICATOR FOR MONOPOLY PRICING /0/,
        ACP             INDICATOR FOR AVERAGE COST PRICING OF TRANSPORT/0/;


*       IN THESE EQUATIONS THE ASSOCIATED VARIABLE IS LISTED AFTER
*       THE DESCRIPTION:


*       INVERSE DEMAND FUNCTIONS (D):

DEMAND(L)..     COEFS(L,"ETA") * D(L) =G= COEFS(L,"RHO") - P(L);


*       NODE BALANCE (C):

SUPPLY(N)..     Y(N)$L(N) + SUM(NP$ARC(NP,N), T(NP,N)) =G=

                X(N)$L(N) + SUM(NP$ARC(N,NP), T(N,NP));

*       SUPPLY-DEMAND BALANCE (P):

MKT(L)..        X(L) =G= D(L);

*       PRICING EQUATION RELATING MARGINAL COST TO CONSUMER PRICE (X):

MRMC(L)..       C(L) =G= P(L) - (X(L) * COEFS(L,"ETA"))$MONOPOLY;

*       TRANSPORT ACTIVITY ZERO PROFIT CONDITION (WITH ADJUSTMENT
*       DEPENDING ON WHETHER SUPPLIERS USE AVERAGE OR MARGINAL COST):

TCOST(N,NP)$ARC(N,NP)..

        C(N) + PAIRS(N,NP,"KAPPA") + (3 - (2)$ACP) *

                 PAIRS(N,NP,"NU") * T(N,NP) * T(N,NP) =G= C(NP);

*       MARGINAL COST EQUATIONS:

COST(L)..        COEFS(L,"ALPHA") + 2 * COEFS(L,"BETA") * Y(L) =G= C(L);


*       DEFINE THE MODEL AND THE EQUATION.VARIABLE ASSOCIATIONS:

MODEL HARKER    /DEMAND.D,SUPPLY.C,MKT.P, MRMC.X,TCOST.T,COST.Y/;


*       ADDITIONAL VARIABLES FOR OLIGOPOLY MODEL:

POSITIVE
VARIABLES
        CC(L,N)         COST OF SUPPLY TO NODE N BY PRODUCER L,
        XX(L,N)         SUPPLY FROM PRODUCER L TO MARKET LP,
        TT(L,N,NP)      SHIPMENTS BY PRODUCER L FROM NODE N TO NP;

*       REVISED EQUATIONS FOR OLIGOPOLY MODEL:

EQUATIONS
                ALTSUPPLY(L,N)          NODE BALANCE EQUATION,
                ALTMKT(L)               DEMAND BALANCE,
                ALTMRMC(LP,N)           PRICING EQUATIONS,
                ALTTCOST(L,N,NP)        TRANSPORT MARGINS,
                ALTCOST(L)              SUPPLY PRICE EQUATION,
                TDEF(N,NP)              TOTAL TRANSPORT DEMAND;

SET  PRD(L,N)   INDICATOR SET FOR PRODUCER TYPE L OPERATING AT NODE N;
PRD(L,N) = NO;
PRD(L,L) = YES;

*       MATERIAL BALANCE:

ALTSUPPLY(LP,N)..

        Y(LP)$PRD(LP,N) + SUM(NP$ARC(NP,N), TT(LP,NP,N)) =G=

                XX(LP,N)$L(N) + SUM(NP$ARC(N,NP), TT(LP,N,NP));

*       DEMAND BALANCE:

ALTMKT(L)..     SUM(LP, XX(LP,L)) =G= D(L);

*       PRICING EQUATION:

ALTMRMC(LP,L)..   CC(LP,L) =G=
                                P(L) - XX(LP,L) * COEFS(L,"ETA");

*       TRANSPORT ACTIVITY ZERO PROFIT CONDITION:

ALTTCOST(L,N,NP)$ARC(N,NP)..

        CC(L,N) + PAIRS(N,NP,"KAPPA") + (3 - (2)$ACP) *

                 PAIRS(N,NP,"NU") * T(N,NP) * T(N,NP) =G= CC(L,NP);

*       TOTAL TRANSPORT DEMAND (THIS EQUATION AND VARIABLE T IS
*       INCLUDED IN THE MONOPOLY MODEL ONLY TO IMPROVE SPARCITY OF
*       THE ALTTCOST CONSTRAINT).

TDEF(N,NP)$ARC(N,NP)..

        T(N,NP) =E= SUM(L, TT(L,N,NP));

*       MARGINAL COST OF SUPPLY:

ALTCOST(L)..

        COEFS(L,"ALPHA") + 2 * COEFS(L,"BETA") * Y(L) =G= CC(L,L);

MODEL HARKOLI  /DEMAND.D,    ALTSUPPLY.CC, ALTMKT.P, ALTMRMC.XX,
                ALTTCOST.TT, ALTCOST.Y, TDEF.T/;

PARAMETERS REP1 TRANSPORT SUMMARY,
           REP2 SUPPLY DEMAND AND PRICE SUMMARY;

T.L(N,NP) = 0;
Y.L(L) = 25;
X.L(N) = 1;
C.L(N) = 1;
D.L(L) = 1;
P.L(L) = 1;
T.FX(N,NP)   $(NOT ARC(N,NP)) = 0;
TT.FX(L,N,NP)$(NOT ARC(N,NP)) = 0;

*       SOLVE FOUR ALTERNATIVE MODELS, ALL BASED ON THE SAME DATA:

*       1. CLASSICAL SPATIAL PRICE EQUILIBRIUM: PERFECTLY COMPETITIVE
*       PRODUCERS AND SUPPLIERS FACING AVERAGE COST PRICING
*       OF TRANSPORTATION:

        MONOPOLY=0; ACP=1;
        SOLVE HARKER USING MCP;
        REP1(N,NP,      "CSPE2") = T.L(N,NP);
        REP2("SUPPLY",L,"CSPE2") = Y.L(L);
        REP2("DEMAND",L,"CSPE2") = D.L(L);
        REP2("PRICE ",L,"CSPE2") = P.L(L);

*       2. MONOPOLY PRICING EQUILIBRIUM IN WHICH THE FIRM OWNS BOTH
*       MEANS OF PRODUCTION AND DISTRIBUTION NETWORK (HENCE, MARGINAL
*       COST PRICING PREVAILS AT BOTH THE FACTORY AND THE RAILHEAD):

        MONOPOLY=1; ACP=0;
        SOLVE HARKER USING MCP;
        REP1(N,NP,      "MONOP1") = T.L(N,NP);
        REP2("SUPPLY",L,"MONOP1") = Y.L(L);
        REP2("DEMAND",L,"MONOP1") = D.L(L);
        REP2("PRICE ",L,"MONOP1") = P.L(L);

*       3. MONOPOLY PRICING EQUILIBRIUM IN WHICH THE FIRM USES THE
*       DISTRIBUTION NETWORK WITH AVERAGE COST PRICING:

        MONOPOLY=1; ACP=1;
        SOLVE HARKER USING MCP;
        REP1(N,NP,      "MONOP2") = T.L(N,NP);
        REP2("SUPPLY",L,"MONOP2") = Y.L(L);
        REP2("DEMAND",L,"MONOP2") = D.L(L);
        REP2("PRICE ",L,"MONOP2") = P.L(L);

*       4. MULTI-PRODUCER OLIGOPOLY MODEL WITH AVERAGE COST PRICING
*       OF TRANSPORTATION LINKS:

        MONOPOLY=0;  ACP=1;
        SOLVE HARKOLI USING MCP;
        REP1(N,NP,      "OLIGOP") = T.L(N,NP);
        REP2("SUPPLY",L,"OLIGOP") = Y.L(L);
        REP2("DEMAND",L,"OLIGOP") = D.L(L);
        REP2("PRICE ",L,"OLIGOP") = P.L(L);

*       COMPARE THE RESULTS FROM THESE COMPUTATIONS WITH THOSE
*       WHICH ARE REPORTED BY GAMS TEST PROBLEM HARKER.85 IN WHICH
*       A CONSUMER-PRODUCER SURPLUS METHODS AND A DIAGONALIZATION
*       ALGORITHM USE MINOS TO SOLVE THE EQUILIBRIUM SYSTEM:


*        DISPLAY REP1, REP2;

</model>

<comments>
From the GAMS Model Library.

A SPATIAL EQUILIBRIUM MODEL IS USED TO DEMONSTRATE DIFFERENT
WAYS OF MODELING MARKET BEHAVIOUR. AN EARLIER VERSION (HARKER)
USED OPTIMISATION TO SOLVE THESE PROBLEMS. IN THIS VERSION,
THE PROBLEMS ARE SOLVED AS COMPLEMENTARITY PROBLEMS.

Reference: Harker P T, Alternative Models of Spatial Competition,
             Operations Research, 34(3), pp 410-425, (1986).
</comments>

</harker>